Код: Выделить всё
{:local adr "username@gmail.com";
:local pass "password";
:local serv [:resolve "smtp.gmail.com"];
tool e-mail send from=$adr to=$adr server=$serv port=587 start-tls=yes user=$adr password=$pass file=file.ca,file.crt,file.key subject=MyFile body=MyFile }Для скрипта пойдет что-то типа:
Код: Выделить всё
{
:log info "Starting Backup Script...";
:local sysname [/system identity get name];
:local sysver [/system package get system version];
:log info "Flushing DNS cache...";
/ip dns cache flush;
:delay 2;
:log info "Deleting last Backups...";
:foreach i in=[/file find] do={:if ([:typeof [:find [/file get $i name] "$sysname-backup-"]]!="nil") do={/file remove $i}};
:delay 2;
:local smtpserv [:resolve "smtp.gmail.com"];
:local Eaccount "username@gmail.com";
:local pass "password";
:local backupfile ("$sysname-backup-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".backup");
:log info "Creating new Full Backup file...";
/system backup save name=$backupfile;
:delay 5;
:local exportfile ("$sysname-backup-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".rsc");
:log info "Creating new Setup Script file...";
/export file=$exportfile;
:delay 5;
:log info "Sending Setup Script file and Full Backup file via E-mail...";
/tool e-mail send from="<$Eaccount>" to=$Eaccount server=$smtpserv port=587 user=$Eaccount password=$pass start-tls=yes file="$backupfile,$exportfile" subject=("$sysname Setup Script Backup (" . [/system clock get date] . ")") body=("$sysname Setup Script file see in attachment.
RouterOS version: $sysver
Time and Date stamp: " . [/system clock get time] . " " . [/system clock get date]);
:delay 30;
:log info "All System Backups emailed successfully.
Backuping completed.";
}Проверяйте, у меня на тестовом прогоне отработало нормально.