Скрипт вывода списка подключенных к роутеру устройств

Здесь выкладываем скрипты
Правила форума
Уважаемые Пользователи форума, обратите внимание!
Ни при каких обстоятельствах, Администрация форума, не несёт ответственности за какой-либо, прямой или косвенный, ущерб причиненный в результате использования материалов, взятых на этом Сайте или на любом другом сайте, на который имеется гиперссылка с данного Сайта. Возникновение неисправностей, потерю программ или данных в Ваших устройствах, даже если Администрация будет явно поставлена в известность о возможности такого ущерба.
Просим Вас быть предельно осторожными и внимательными, в использовании материалов раздела. Учитывать не только Ваши пожелания, но и границы возможностей вашего оборудования.
Аватара пользователя
drpioneer
Сообщения: 142
Зарегистрирован: 30 май 2013, 10:20

Добрый вечер.
podarok66 писал(а): 05 сен 2020, 20:51 Два интересных момента.
1. Что такое !!!ATTENTION!!! An error occurred when creating list N2 ?
2. И зачем точка с запятой везде в выводе присутствует?
1. Это отладочная информация. В данном случае возникли проблемы при создании списка: [/interface bridge host find], так как для его формирования используется информация из [/ip dhcp-server lease ], где могут отсутствовать искомые данные.
Вывод отладочной инфы убрал.

2. Это особенность вывода массива построчно. На тот момент я ещё не придумал, как его вывести без точек с запятыми.
Теперь вывод массива исправил.

Ниже представлен подправленный код:

Код: Выделить всё


# Script for building a network table
# https://forummikrotik.ru/viewtopic.php?p=70575
# tested on ROS 6.47
# updated 2020/09/06

# interface list
:global interfaceIndexArray 0;
:global interfaceArray {"";"";"";"";""};
foreach interfaceIndex in=[ /interface find running=yes; ] do={
    :do {
        :local interfaceName ([ /interface get $interfaceIndex name; ]);
        :local interfaceComment ([:tostr [ /interface get $interfaceIndex comment; ]]);
        :local interfaceMAC ([:tostr [ /interface get $interfaceIndex mac-address; ]]);
        :local interfaceHost ([ /system resource get board-name; ]);
        :set ($interfaceArray->$interfaceIndexArray) {$interfaceName;$interfaceHost;$interfaceMAC;"";$interfaceComment};
        :set interfaceIndexArray ($interfaceIndexArray + 1);
    } on-error={ }
}
:set interfaceIndexArray ($interfaceIndexArray - 1);
    
# interface bridge host list
:global bridgeHostIndexArray 0;
:global bridgeHostArray {"";"";"";"";"";""};
foreach bridgeHost in=[ /interface bridge host find; ] do={
    :do {
        :local hostMAC ([ /interface bridge host get $bridgeHost mac-address; ]);
        :local hostBridge ([ /interface bridge host get $bridgeHost bridge; ]);
        :local hostInterface ([ /interface bridge host get $bridgeHost on-interface; ]);
        :local hostComment ("");
        :local hostName ("");
        :local hostIP ("");
        if ([ /interface bridge host get $bridgeHost local; ] = true) do={ 
            :set hostName ([ /system resource get board-name; ]);
            :set hostIP ([ /ip address get [ find interface=$hostBridge ] address; ]);
            :set hostIP ([:pick $hostIP 0 [:find $hostIP "/"]]);
        } else={
            :do {
                :set hostName ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] host-name; ]);
                :set hostIP ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] address; ]);
                :set hostComment ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] comment; ]);
            } on-error={ 
                :set hostName ([ /ip dhcp-server lease get [ find mac-address=$hostMAC dynamic=yes ] host-name; ]);
                :set hostIP ([ /ip dhcp-server lease get [ find mac-address=$hostMAC dynamic=yes ] address; ]);
            }
        }
        :set ($bridgeHostArray->$bridgeHostIndexArray) {$hostInterface;$hostName;$hostMAC;$hostIP;$hostBridge;$hostComment};
        :set bridgeHostIndexArray ($bridgeHostIndexArray + 1);
    } on-error={ }
}
:set bridgeHostIndexArray ($bridgeHostIndexArray - 1);
    
# ip address list
:global ipAddressIndexArray 0;
:global ipAddressArray {"";"";"";""};
foreach ipAddress in=([ /ip address find; ]) do={
    :do {
        :local ipAddressInterface ([ /ip address get $ipAddress interface; ]); 
        :local ipAddressIP ([ /ip address get $ipAddress address; ]); 
        :set ipAddressIP ([:pick $ipAddressIP 0 [:find $ipAddressIP "/"]]);
        :local ipAddressComment ([ /ip address get $ipAddress comment; ]); 
        :local ipAddressNetwork ([ /ip address get $ipAddress network; ]);
        if ([:tostr ($ipAddressIP)] != "") do={ 
            :set ($ipAddressArray->$ipAddressIndexArray) {$ipAddressInterface;$ipAddressIP;$ipAddressNetwork;$ipAddressComment};
            :set ipAddressIndexArray ($ipAddressIndexArray + 1);
        }
    } on-error={ } 
}
:set ipAddressIndexArray ($ipAddressIndexArray - 1);

# ip arp list
:global ipArpIndexArray 0;
:global ipArpArray {"";"";"";"";""}; 
foreach ipArp in=([ /ip arp find; ]) do={
    :do {
        :local ipArpInterface ([ /ip arp get $ipArp interface; ]); 
        :local ipArpIP ([ /ip arp get $ipArp address; ]); 
        :local ipArpComment ([ /ip arp get $ipArp comment; ]); 
        :local ipArpMACAddress ([ /ip arp get $ipArp mac-address; ]);
        :set ($ipArpArray->$ipArpIndexArray) {$ipArpInterface;"ARP";$ipArpMACAddress;$ipArpIP;$ipArpComment};
        :set ipArpIndexArray ($ipArpIndexArray + 1);
    } on-error={ } 
}
:set ipArpIndexArray ($ipArpIndexArray - 1);

# ip dhcp list
:global ipDhcpIndexArray 0;
:global ipDhcpArray {"";"";"";"";""}; 
foreach ipDhcp in=([ /ip dhcp-server lease find; ]) do={
    :do {
        :local ipDhcpName ([ /ip dhcp-server lease get $ipDhcp host-name; ]); 
        :local ipDhcpIP ([ /ip dhcp-server lease get $ipDhcp address; ]); 
        :local ipDhcpComment ([ /ip dhcp-server lease get $ipDhcp comment; ]); 
        :local ipDhcpMAC ([ /ip dhcp-server lease get $ipDhcp mac-address; ]);
        :set ($ipDhcpArray->$ipDhcpIndexArray) {"DHCP";$ipDhcpName;$ipDhcpMAC;$ipDhcpIP;$ipDhcpComment};
        :set ipDhcpIndexArray ($ipDhcpIndexArray + 1);
    } on-error={ } 
}
:set ipDhcpIndexArray ($ipDhcpIndexArray - 1);
    
# ip route list
:global ipRoutesIndexArray 0;
:global ipRoutesArray {"";"";"";"";""}; 
foreach ipRoutes in=([ /ip route find active=yes distance=0;]) do={
    :do {
        :local ipRouteName ([ /ip route get $ipRoutes gateway; ]); 
        :local ipRouteIP ([ /ip route get $ipRoutes pref-src; ]); 
        :local ipRouteComment ([ /ip route get $ipRoutes comment; ]); 
        :local ipRouteDstAddr ([ /ip route get $ipRoutes dst-address; ]);
        :set ipRouteDstAddr ([:pick $ipRouteDstAddr 0 [:find $ipRouteDstAddr "/"]]);
        :set ($ipRoutesArray->$ipRoutesIndexArray) {$ipRouteName;"ROUTE";$ipRouteDstAddr;$ipRouteIP;$ipRouteComment};
        :set ipRoutesIndexArray ($ipRoutesIndexArray + 1);
    } on-error={ } 
}
:set ipRoutesIndexArray ($ipRoutesIndexArray - 1);

# build new list
:global n 2;
:global newArray {"";"";"";"";"";"";""};
:set ($newArray->0) {"NUMBER";"INTERFACE";"HOST NAME";"MAC ADDRESS";"IP ADDRESS";"BRIDGE";"COMMENT"};
:set ($newArray->1) {"";"";"";"";"";"";""};
for i from=0 to=$interfaceIndexArray do={
    for j from=0 to=$bridgeHostIndexArray do={
        :local findDestination [:find key=($bridgeHostArray->$j->0) in=($interfaceArray->$i)];
        if ([:tostr [$findDestination]] != "" && ($bridgeHostArray->$j->4) != ($bridgeHostArray->$j->0)) do={
            if (($bridgeHostArray->$j->2) = ($interfaceArray->$i->2)) do={
                :set ($newArray->$n) {$n-1;($bridgeHostArray->$j->0);($bridgeHostArray->$j->1);($bridgeHostArray->$j->2);($bridgeHostArray->$j->3);($bridgeHostArray->$j->4);($interfaceArray->$i->4)}; 
            } else={
                :set ($newArray->$n) {$n-1;($bridgeHostArray->$j->0);($bridgeHostArray->$j->1);($bridgeHostArray->$j->2);($bridgeHostArray->$j->3);($bridgeHostArray->$j->4);($bridgeHostArray->$j->5)}; 
            }
            :set n ($n + 1);
        }
    }
    for j from=0 to=$ipAddressIndexArray do={
        :local findDestination [:find key=($interfaceArray->$i->0) in=($ipAddressArray->$j)];
        if ([:tostr [$findDestination]] != "") do={
            :set ($newArray->$n) {$n-1;($interfaceArray->$i->0);($interfaceArray->$i->1);($interfaceArray->$i->2);($ipAddressArray->$j->1);($ipAddressArray->$j->2);($interfaceArray->$i->4)}; 
            :set n ($n + 1);
        }
    }
}
:set n ($n - 1);

# list output to terminal
for i from=0 to=$n do={
    :set ($newArray->$i->0) ([:pick [:tostr [($newArray->$i->0 . "                         ")]] 0  6 ]);
    :set ($newArray->$i->1) ([:pick [:tostr [($newArray->$i->1 . "                         ")]] 0 21 ]);
    :set ($newArray->$i->2) ([:pick [:tostr [($newArray->$i->2 . "                         ")]] 0 25 ]);
    :set ($newArray->$i->3) ([:pick [:tostr [($newArray->$i->3 . "                         ")]] 0 19 ]);
    :set ($newArray->$i->4) ([:pick [:tostr [($newArray->$i->4 . "                         ")]] 0 17 ]);
    :set ($newArray->$i->5) ([:pick [:tostr [($newArray->$i->5 . "                         ")]] 0 17 ]);
    :set ($newArray->$i->6) ([:pick [:tostr [($newArray->$i->6 . "                         ")]] 0 25 ]);
    :put (($newArray->$i->0)." ".($newArray->$i->1)." ".($newArray->$i->2)." ".($newArray->$i->3)." ".($newArray->$i->4)." ".($newArray->$i->5)." ".($newArray->$i->6));
}


Замечания/предложения приветствуются.


Аватара пользователя
podarok66
Модератор
Сообщения: 4355
Зарегистрирован: 11 фев 2012, 18:49
Откуда: МО

Отличный скрипт получился. Прошу разрешения утащить в ЖЖшку к себе. Естественно, со ссылкой на форум и автора скрипта ...
Вот интересно, у меня кроме приведённых интерфейсов, есть ещё туннель до брокера IPv6, потому как провайдер этим заниматься категорически не желает. Так вот, этот интерфейс в перечисление не попадает. Видимо, он не определяется как активный...Хотя трафик через него бегает
Изображение


Мануалы изучил и нигде не ошибся? Фаервол отключил? Очереди погасил? Витая пара проверена? ... Тогда Netinstal'ом железку прошей и настрой ее заново. Что, все равно не фурычит? Тогда к нам. Если не подскажем, хоть посочувствуем...
Аватара пользователя
drpioneer
Сообщения: 142
Зарегистрирован: 30 май 2013, 10:20

podarok66 писал(а): 06 сен 2020, 18:53 Отличный скрипт получился.
Благодарю за отзыв.
Прошу разрешения утащить в ЖЖшку к себе. Естественно, со ссылкой на форум и автора скрипта ...
Ничего против не имею.
Вот интересно, у меня кроме приведённых интерфейсов, есть ещё туннель до брокера IPv6, потому как провайдер этим заниматься категорически не желает. Так вот, этот интерфейс в перечисление не попадает. Видимо, он не определяется как активный...Хотя трафик через него бегает
Ещё не все хотелки реализованы и не все косяки пофикшены. Надеюсь удастся решить проблему в одной из следующих версий скрипта.


Аватара пользователя
podarok66
Модератор
Сообщения: 4355
Зарегистрирован: 11 фев 2012, 18:49
Откуда: МО

drpioneer писал(а): 06 сен 2020, 19:21 Ничего против не имею.
Спасибо
drpioneer писал(а): 06 сен 2020, 19:21 Ещё не все хотелки реализованы и не все косяки пофикшены. Надеюсь удастся решить проблему в одной из следующих версий скрипта.
Это даже не хотелка, просто заметил, доложил по команде, чтобы было понятно, что я честный тестировщик :-)


Мануалы изучил и нигде не ошибся? Фаервол отключил? Очереди погасил? Витая пара проверена? ... Тогда Netinstal'ом железку прошей и настрой ее заново. Что, все равно не фурычит? Тогда к нам. Если не подскажем, хоть посочувствуем...
yarvelov
Сообщения: 92
Зарегистрирован: 15 июл 2018, 02:08

Странно, вчера его запускал на 3 железках и во всех случаях он просто висел, сегодня все отрабатывает :ps_ih:
Еще бы статику он опрашивал)


Аватара пользователя
podarok66
Модератор
Сообщения: 4355
Зарегистрирован: 11 фев 2012, 18:49
Откуда: МО

Вот кстати, возник вопрос. А зачем такое количество переменных именно global? Это обязательно для работы скрипта? Или локальных переменных тоже хватило бы?


Мануалы изучил и нигде не ошибся? Фаервол отключил? Очереди погасил? Витая пара проверена? ... Тогда Netinstal'ом железку прошей и настрой ее заново. Что, все равно не фурычит? Тогда к нам. Если не подскажем, хоть посочувствуем...
Аватара пользователя
drpioneer
Сообщения: 142
Зарегистрирован: 30 май 2013, 10:20

Приветствую.
podarok66 писал(а): 07 сен 2020, 20:09 А зачем такое количество переменных именно global? Это обязательно для работы скрипта? Или локальных переменных тоже хватило бы?
С локальными не прокатывает... Сделал удаление глобальных переменных после отработки скрипта, как описано тут: viewtopic.php?f=14&t=11991
yarvelov писал(а): 06 сен 2020, 21:38 Еще бы статику он опрашивал)
Что означает "статику"? О чём речь?

Подправленный вариант скрипта:

Код: Выделить всё



# Script for building a network table
# https://forummikrotik.ru/viewtopic.php?p=70575
# tested on ROS 6.47
# updated 2020/09/09

# interface list
:global interfaceIndexArray 0;
:global interfaceArray {"";"";"";""};
foreach interfaceIndex in=[ /interface find running=yes; ] do={
    :local interfaceName ([ /interface get $interfaceIndex name; ]);
    :local interfaceComment ([:tostr [ /interface get $interfaceIndex comment; ]]);
    :local interfaceMAC ([:tostr [ /interface get $interfaceIndex mac-address; ]]);
    :local interfaceHost ([ /system resource get board-name; ]);
    :set ($interfaceArray->$interfaceIndexArray) {$interfaceName;$interfaceHost;$interfaceMAC;$interfaceComment};
    :set interfaceIndexArray ($interfaceIndexArray + 1);
}
:set interfaceIndexArray ($interfaceIndexArray - 1);

# interface bridge host list
:global bridgeHostIndexArray 0;
:global bridgeHostArray {"";"";"";"";"";""};
foreach bridgeHost in=[ /interface bridge host find; ] do={
    :do {
        :local hostMAC ([ /interface bridge host get $bridgeHost mac-address; ]);
        :local hostBridge ([ /interface bridge host get $bridgeHost bridge; ]);
        :local hostInterface ([ /interface bridge host get $bridgeHost on-interface; ]);
        :local hostComment ("");
        :local hostName ("");
        :local hostIP ("");
        if ([ /interface bridge host get $bridgeHost local; ] = true) do={ 
            :set hostName ([ /system resource get board-name; ]);
            :set hostIP ([ /ip address get [ find interface=$hostBridge ] address; ]);
            :set hostIP ([:pick $hostIP 0 [:find $hostIP "/"]]);
        } else={
            :do {
                :set hostName ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] host-name; ]);
                :set hostIP ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] address; ]);
                :set hostComment ([ /ip dhcp-server lease get [ find mac-address=$hostMAC ] comment; ]);
            } on-error={ 
                :set hostName ([ /ip dhcp-server lease get [ find mac-address=$hostMAC dynamic=yes ] host-name; ]);
                :set hostIP ([ /ip dhcp-server lease get [ find mac-address=$hostMAC dynamic=yes ] address; ]);
            }
        }
        :set ($bridgeHostArray->$bridgeHostIndexArray) {$hostInterface;$hostName;$hostMAC;$hostIP;$hostBridge;$hostComment};
        :set bridgeHostIndexArray ($bridgeHostIndexArray + 1);
    } on-error={ }
}
:set bridgeHostIndexArray ($bridgeHostIndexArray - 1);

# ip address list
:global ipAddressIndexArray 0;
:global ipAddressArray {"";"";"";""};
foreach ipAddress in=([ /ip address find; ]) do={
    :local ipAddressInterface ([ /ip address get $ipAddress interface; ]); 
    :local ipAddressIP ([ /ip address get $ipAddress address; ]); 
    :set ipAddressIP ([:pick $ipAddressIP 0 [:find $ipAddressIP "/"]]);
    :local ipAddressComment ([ /ip address get $ipAddress comment; ]); 
    :local ipAddressNetwork ([ /ip address get $ipAddress network; ]);
    if ([:tostr ($ipAddressIP)] != "") do={ 
        :set ($ipAddressArray->$ipAddressIndexArray) {$ipAddressInterface;$ipAddressIP;$ipAddressNetwork;$ipAddressComment};
        :set ipAddressIndexArray ($ipAddressIndexArray + 1);
    }
}
:set ipAddressIndexArray ($ipAddressIndexArray - 1);

# ip arp list
:global ipArpIndexArray 0;
:global ipArpArray {"";"";"";""}; 
foreach ipArp in=([ /ip arp find; ]) do={
    :local ipArpInterface ([ /ip arp get $ipArp interface; ]); 
    :local ipArpIP ([ /ip arp get $ipArp address; ]); 
    :local ipArpComment ([ /ip arp get $ipArp comment; ]); 
    :local ipArpMACAddress ([ /ip arp get $ipArp mac-address; ]);
    :set ($ipArpArray->$ipArpIndexArray) {$ipArpInterface;$ipArpMACAddress;$ipArpIP;$ipArpComment};
    :set ipArpIndexArray ($ipArpIndexArray + 1);
}
:set ipArpIndexArray ($ipArpIndexArray - 1);

# ip dhcp list
:global ipDhcpIndexArray 0;
:global ipDhcpArray {"";"";"";""}; 
foreach ipDhcp in=([ /ip dhcp-server lease find; ]) do={
    :local ipDhcpName ([ /ip dhcp-server lease get $ipDhcp host-name; ]); 
    :local ipDhcpIP ([ /ip dhcp-server lease get $ipDhcp address; ]); 
    :local ipDhcpComment ([ /ip dhcp-server lease get $ipDhcp comment; ]); 
    :local ipDhcpMAC ([ /ip dhcp-server lease get $ipDhcp mac-address; ]);
    :set ($ipDhcpArray->$ipDhcpIndexArray) {$ipDhcpName;$ipDhcpMAC;$ipDhcpIP;$ipDhcpComment};
    :set ipDhcpIndexArray ($ipDhcpIndexArray + 1);
}
:set ipDhcpIndexArray ($ipDhcpIndexArray - 1);

# ip route list
:global ipRoutesIndexArray 0;
:global ipRoutesArray {"";"";"";""}; 
foreach ipRoutes in=([ /ip route find active=yes distance=0;]) do={
    :local ipRouteName ([ /ip route get $ipRoutes gateway; ]); 
    :local ipRouteIP ([ /ip route get $ipRoutes pref-src; ]); 
    :local ipRouteComment ([ /ip route get $ipRoutes comment; ]); 
    :local ipRouteDstAddr ([ /ip route get $ipRoutes dst-address; ]);
    :set ipRouteDstAddr ([:pick $ipRouteDstAddr 0 [:find $ipRouteDstAddr "/"]]);
    :set ($ipRoutesArray->$ipRoutesIndexArray) {$ipRouteName;$ipRouteDstAddr;$ipRouteIP;$ipRouteComment};
    :set ipRoutesIndexArray ($ipRoutesIndexArray + 1);
}
:set ipRoutesIndexArray ($ipRoutesIndexArray - 1);

# build new list
:global newIndexArray 2;
:global newArray {"";"";"";"";"";"";""};
:set ($newArray->0) {"NUMBER";"INTERFACE";"HOST NAME";"MAC ADDRESS";"IP ADDRESS";"BRIDGE";"COMMENT"};
:set ($newArray->1) {"";"";"";"";"";"";""};
for i from=0 to=$interfaceIndexArray do={
    for j from=0 to=$bridgeHostIndexArray do={
        :local findDestination [:find key=($bridgeHostArray->$j->0) in=($interfaceArray->$i)];
        if ([:tostr [$findDestination]] != "" && ($bridgeHostArray->$j->4) != ($bridgeHostArray->$j->0)) do={
            if (($bridgeHostArray->$j->2) = ($interfaceArray->$i->2)) do={
                :set ($newArray->$newIndexArray) {$newIndexArray-1;($bridgeHostArray->$j->0);($bridgeHostArray->$j->1);($bridgeHostArray->$j->2);($bridgeHostArray->$j->3);($bridgeHostArray->$j->4);($interfaceArray->$i->3)}; 
            } else={
                :set ($newArray->$newIndexArray) {$newIndexArray-1;($bridgeHostArray->$j->0);($bridgeHostArray->$j->1);($bridgeHostArray->$j->2);($bridgeHostArray->$j->3);($bridgeHostArray->$j->4);($bridgeHostArray->$j->5)}; 
            }
            :set newIndexArray ($newIndexArray + 1);
        }
    }
    for j from=0 to=$ipAddressIndexArray do={
        :local findDestination [:find key=($interfaceArray->$i->0) in=($ipAddressArray->$j)];
        if ([:tostr [$findDestination]] != "") do={
            :set ($newArray->$newIndexArray) {$newIndexArray-1;($interfaceArray->$i->0);($interfaceArray->$i->1);($interfaceArray->$i->2);($ipAddressArray->$j->1);($ipAddressArray->$j->2);($interfaceArray->$i->3)}; 
            :set newIndexArray ($newIndexArray + 1);
        }
    }
}
:set newIndexArray ($newIndexArray - 1);

# list output to terminal
for i from=0 to=$newIndexArray do={
    :set ($newArray->$i->0) ([:pick [:tostr [($newArray->$i->0 . "                         ")]] 0  6 ]);
    :set ($newArray->$i->1) ([:pick [:tostr [($newArray->$i->1 . "                         ")]] 0 21 ]);
    :set ($newArray->$i->2) ([:pick [:tostr [($newArray->$i->2 . "                         ")]] 0 25 ]);
    :set ($newArray->$i->3) ([:pick [:tostr [($newArray->$i->3 . "                         ")]] 0 19 ]);
    :set ($newArray->$i->4) ([:pick [:tostr [($newArray->$i->4 . "                         ")]] 0 17 ]);
    :set ($newArray->$i->5) ([:pick [:tostr [($newArray->$i->5 . "                         ")]] 0 17 ]);
    :set ($newArray->$i->6) ([:pick [:tostr [($newArray->$i->6 . "                         ")]] 0 35 ]);
    :put (($newArray->$i->0)." ".($newArray->$i->1)." ".($newArray->$i->2)." ".($newArray->$i->3)." ".($newArray->$i->4)." ".($newArray->$i->5)." ".($newArray->$i->6));
}

# clearing variables
:set interfaceIndexArray (:);
:set interfaceArray (:);
:set bridgeHostIndexArray (:);
:set bridgeHostArray (:);
:set ipAddressIndexArray (:);
:set ipAddressArray (:);
:set ipArpIndexArray (:);
:set ipArpArray (:);
:set ipDhcpIndexArray (:);
:set ipDhcpArray (:);
:set ipRoutesIndexArray (:);
:set ipRoutesArray (:);
:set newIndexArray (:);
:set newArray (:);


Замечания/дополнения приветствуются.


evgeniy.demin
Сообщения: 4
Зарегистрирован: 27 июл 2020, 13:47

Чтобы статику выводить нужно не dhcp смотреть а ARP


Аватара пользователя
podarok66
Модератор
Сообщения: 4355
Зарегистрирован: 11 фев 2012, 18:49
Откуда: МО

drpioneer писал(а): 09 сен 2020, 01:39 С локальными не прокатывает...
Странно, у меня прокатило :sh_ok: Тупо с текстовом редакторе заменил все global на local и всё отработало в штатном режиме...


Мануалы изучил и нигде не ошибся? Фаервол отключил? Очереди погасил? Витая пара проверена? ... Тогда Netinstal'ом железку прошей и настрой ее заново. Что, все равно не фурычит? Тогда к нам. Если не подскажем, хоть посочувствуем...
yarvelov
Сообщения: 92
Зарегистрирован: 15 июл 2018, 02:08

drpioneer писал(а): 09 сен 2020, 01:39
Что означает "статику"? О чём речь?

Ну устройства со статическими адресами которых нет в dhcp.


Ответить