есть несколько впн туннелей через pptp до соседних офисов.
И если кто то садится на интернет канал и загружает его, начиная скачивать много, да пусть даже те же обновления винда вдруг начинает подтягивать - впн не отваливается, но удаленная сеть становится сразу недоступной. тот же RDP сразу виснет.
Как правильно настроить, дабы подобного не случалось больше?
Настройка приоритезации трафика...
-
- Сообщения: 69
- Зарегистрирован: 28 мар 2019, 08:40
Никто не знает или же это настолько очевидный вопрос, что не считается нужным ответить? :)
просто на rb2011 такого не было, все работало нормально, а на rb3011 вот стабильно. как пошла, к примеру винда обновляться - vpn ложится. а если не ложится - то трафик через него все равно не ходит....
просто на rb2011 такого не было, все работало нормально, а на rb3011 вот стабильно. как пошла, к примеру винда обновляться - vpn ложится. а если не ложится - то трафик через него все равно не ходит....
-
- Сообщения: 1778
- Зарегистрирован: 09 июл 2014, 12:33
Тут не дают готовых рецептов, а помогают, когда видно, что есть процесс, которому можно помочь.Bushi писал(а): ↑13 май 2019, 10:39 Никто не знает или же это настолько очевидный вопрос, что не считается нужным ответить? :)
просто на rb2011 такого не было, все работало нормально, а на rb3011 вот стабильно. как пошла, к примеру винда обновляться - vpn ложится. а если не ложится - то трафик через него все равно не ходит....
Конфиги на заказ готовят разделом ниже, в "платных услугах".
Начните с ознакомления https://wiki.mikrotik.com/wiki/Traffic_ ... lemetation
Попробуйте реализовать у себя, и с конкретными проблемами, если возникнут, с приложением конфигураций и схем уже обращайтесь.
-
- Сообщения: 16
- Зарегистрирован: 22 апр 2019, 19:46
Ну, вот пример простой приоритезации... На основании него можете сделать правила для интересующего Вас трафика.
Код: Выделить всё
/ip firewall mangle
add action=mark-connection chain=prerouting comment=Managment connection-state=new dst-port=8291,22 \
new-connection-mark=ManageTraff_conn passthrough=yes protocol=tcp
add action=mark-packet chain=prerouting connection-mark=ManageTraff_conn new-packet-mark=ManageTraff_Packets \
passthrough=no
add action=mark-connection chain=prerouting comment=SIP connection-state=new dst-address-list=\
SIP_External_Servers new-connection-mark=SIP_Conn passthrough=yes src-address-list=\
SIP_Internal_Servers/Clients
add action=mark-connection chain=prerouting connection-state=new dst-address-list=\
SIP_Internal_Servers/Clients new-connection-mark=SIP_Conn passthrough=yes src-address-list=\
SIP_External_Servers
add action=mark-packet chain=prerouting connection-mark=SIP_Conn new-packet-mark=SIP_Packets passthrough=no
add action=mark-connection chain=prerouting comment=DNS connection-state=new dst-port=53 new-connection-mark=\
DNS_conn passthrough=yes protocol=tcp
add action=mark-connection chain=prerouting connection-state=new dst-port=53 new-connection-mark=DNS_conn \
passthrough=yes protocol=udp
add action=mark-packet chain=prerouting connection-mark=DNS_conn new-packet-mark=DNS_Packets passthrough=no
add action=mark-connection chain=prerouting comment=HTTP connection-state=new dst-port=80,443 \
new-connection-mark=HTTP_Conn passthrough=yes protocol=tcp
add action=mark-packet chain=prerouting connection-mark=HTTP_Conn new-packet-mark=HTTP_Packets passthrough=no
add action=mark-connection chain=prerouting comment=RDP connection-state=new dst-port=3389 \
new-connection-mark=RDP_Conn passthrough=yes protocol=tcp
add action=mark-packet chain=prerouting connection-mark=RDP_Conn new-packet-mark=RDP_Packets passthrough=no
add action=mark-connection chain=prerouting comment="Other traffic" connection-mark=no-mark connection-state=\
new new-connection-mark=Other_traff_conn passthrough=yes
add action=mark-packet chain=prerouting connection-mark=Other_traff_conn new-packet-mark=Other_traff_packets \
passthrough=no
/queue type
add kind=pcq name=SIP pcq-classifier=src-address,dst-address,src-port,dst-port pcq-limit=10KiB pcq-rate=160k
/queue simple
add dst=ether1 name=ISP1 target=bridge total-max-limit=50M
add dst=ether1 name=ManTraff packet-marks=ManTraff_Packets parent=ISP1 priority=2/2 target=bridge \
total-max-limit=50M
add dst=ether1 name=DNS-wan1 packet-marks=DNS_Packets parent=ISP1 priority=3/3 target=bridge total-max-limit=\
50M
add dst=ether1 name=SIP packet-marks=SIP_Packets parent=ISP1 priority=1/1 target=bridge total-max-limit=50M \
total-queue=SIP
add dst=ether1 name=RDP packet-marks=RDP_Packets parent=ISP1 priority=4/4 target=bridge total-max-limit=50M \
total-queue=pcq-download-default
add dst=ether1 name=HTTP packet-marks=HTTP_Packets parent=ISP1 priority=6/6 target=bridge total-max-limit=50M \
total-queue=pcq-download-default
add dst=ether1 name=Other packet-marks=Other_traff_packets parent=ISP1 priority=7/7 target=bridge \
total-max-limit=50M total-queue=pcq-download-default
-
- Сообщения: 1
- Зарегистрирован: 06 фев 2017, 05:40
поделюсь своей приоритезации трафика
Код: Выделить всё
/ip firewall address-list
;;внутреняя сеть
add address=192.168.5.0/24 list=LAN
;; сеть впн
add address=192.168.5.0/24 list=LAN-EXCEPTION
/queue type
add kind=pcq name=PCQ-DOWNLOAD pcq-classifier=dst-address
add kind=pcq name=PCQ-UPLOAD pcq-classifier=src-address
/queue tree
;; скорость входящего канала
add max-limit=60M name=DOWNLOAD parent=global
add name=SUPER-HIGH-DOWNLOAD packet-mark=SUPER-HIGH-DOWNLOAD parent=DOWNLOAD \
priority=1 queue=PCQ-DOWNLOAD
add name=HIGH-DOWNLOAD packet-mark=HIGH-DOWNLOAD parent=DOWNLOAD priority=2 \
queue=PCQ-DOWNLOAD
add name=NORMAL-DOWNLOAD packet-mark=NORMAL-DOWNLOAD parent=DOWNLOAD \
priority=3 queue=PCQ-DOWNLOAD
add name=LOW-DOWNLOAD packet-mark=LOW-DOWNLOAD parent=DOWNLOAD priority=4 \
queue=PCQ-DOWNLOAD
;; скорость исходящего канала
add max-limit=30M name=UPLOAD parent=global
add name=SUPER-HIGH-UPLOAD packet-mark=SUPER-HIGH-UPLOAD parent=UPLOAD \
priority=1 queue=PCQ-UPLOAD
add name=HIGH-UPLOAD packet-mark=HIGH-UPLOAD parent=UPLOAD priority=2 queue=\
PCQ-UPLOAD
add name=NORMAL-UPLOAD packet-mark=NORMAL-UPLOAD parent=UPLOAD priority=3 \
queue=PCQ-UPLOAD
add name=LOW-UPLOAD packet-mark=LOW-UPLOAD parent=UPLOAD priority=4 queue=\
PCQ-UPLOAD
/ip firewall mangle
add action=accept chain=forward comment="############## LOW #############" \
disabled=yes
add action=mark-connection chain=forward comment=ALL-TRAFFIC \
new-connection-mark=LOW passthrough=yes
add action=mark-packet chain=forward comment=LOW-DOWNLOAD connection-mark=LOW \
dst-address-list=LAN new-packet-mark=LOW-DOWNLOAD passthrough=yes \
src-address-list=!LAN-EXCEPTION
add action=mark-packet chain=prerouting comment=LOW-UPLOAD connection-mark=\
LOW dst-address-list=!LAN-EXCEPTION new-packet-mark=LOW-UPLOAD \
passthrough=yes src-address-list=LAN
add action=accept chain=forward comment="############## END LOW #########" \
disabled=yes
add action=accept chain=forward comment="############## NORMAL #########" \
disabled=yes
add action=mark-connection chain=forward comment=HTTP new-connection-mark=\
NORMAL passthrough=yes port=80 protocol=tcp
add action=mark-connection chain=forward comment=HTTPS new-connection-mark=\
NORMAL passthrough=yes port=443 protocol=tcp
add action=mark-connection chain=forward comment=Proxy new-connection-mark=\
NORMAL passthrough=yes port=3128,8080,8082 protocol=tcp
add action=mark-connection chain=forward comment=FTP new-connection-mark=\
NORMAL passthrough=yes port=20,21 protocol=tcp
add action=mark-connection chain=forward comment=SMTP new-connection-mark=\
NORMAL passthrough=yes port=25 protocol=tcp
add action=mark-connection chain=forward comment=SMTPS new-connection-mark=\
NORMAL passthrough=yes port=465 protocol=tcp
add action=mark-connection chain=forward comment=IMAP dst-port=143 \
new-connection-mark=NORMAL passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=POP3 dst-port=110 \
new-connection-mark=NORMAL passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=POP3S dst-port=995 \
new-connection-mark=NORMAL passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=IMAPS dst-port=993 \
new-connection-mark=NORMAL passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment="100Kb Connections" \
connection-bytes=0-100000 new-connection-mark=NORMAL passthrough=yes \
protocol=tcp
add action=mark-packet chain=forward comment=NORMAL-DOWNLOAD connection-mark=\
NORMAL dst-address-list=LAN new-packet-mark=NORMAL-DOWNLOAD passthrough=\
yes src-address-list=!LAN-EXCEPTION
add action=mark-packet chain=prerouting comment=NORMAL-UPLOAD \
connection-mark=NORMAL dst-address-list=!LAN-EXCEPTION new-packet-mark=\
NORMAL-UPLOAD passthrough=yes src-address-list=LAN
add action=accept chain=forward comment=\
"############## END NORMAL ############" disabled=yes
add action=accept chain=forward comment="############## HIGH ############" \
disabled=yes
add action=mark-connection chain=forward comment=SSH new-connection-mark=HIGH \
packet-size=0-1400 passthrough=yes port=22 protocol=tcp
add action=mark-connection chain=forward comment=TELNET new-connection-mark=\
HIGH passthrough=yes port=23 protocol=tcp
add action=mark-connection chain=forward comment=SNMP new-connection-mark=\
HIGH passthrough=yes port=161-162 protocol=tcp
add action=mark-connection chain=forward comment=PPTP new-connection-mark=\
HIGH passthrough=yes port=1723 protocol=tcp
add action=mark-connection chain=forward comment=L2TP dst-port=1701 \
new-connection-mark=HIGH passthrough=yes protocol=udp
add action=mark-connection chain=forward comment=SIP new-connection-mark=HIGH \
passthrough=yes port=5060 protocol=udp
add action=mark-connection chain=forward comment=GRE new-connection-mark=HIGH \
passthrough=yes protocol=gre
add action=mark-connection chain=forward comment="50Kb Connections" \
connection-bytes=0-50000 new-connection-mark=HIGH passthrough=yes \
protocol=tcp
add action=mark-packet chain=forward comment=HIGH-DOWNLOAD connection-mark=\
HIGH dst-address-list=LAN new-packet-mark=HIGH-DOWNLOAD passthrough=yes \
src-address-list=!LAN-EXCEPTION
add action=mark-packet chain=prerouting comment=HIGH-UPLOAD connection-mark=\
HIGH dst-address-list=!LAN-EXCEPTION new-packet-mark=HIGH-UPLOAD \
passthrough=yes src-address-list=LAN
add action=accept chain=forward comment="############## END HIGH ##########" \
disabled=yes
add action=accept chain=forward comment=\
"############## SUPER-HIGH ##########" disabled=yes
add action=mark-connection chain=forward comment=DNS dst-port=53 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=tcp src-port=53
add action=mark-connection chain=forward comment=DNS dst-port=53 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=DNS dst-port=53 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=udp
add action=mark-connection chain=forward comment=NNTP dst-port=119 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=Winbox dst-port=8291 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=ntp dst-port=123 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=udp
add action=mark-connection chain=forward comment=VNC new-connection-mark=\
SUPER-HIGH passthrough=yes port=5900-5901 protocol=tcp
add action=mark-connection chain=forward comment=RDP dst-port=3389 \
new-connection-mark=SUPER-HIGH passthrough=yes protocol=tcp
add action=mark-connection chain=forward comment=PING new-connection-mark=\
SUPER-HIGH passthrough=yes protocol=icmp
add action=mark-connection chain=forward comment="5Kb Connections" \
connection-bytes=0-5000 new-connection-mark=SUPER-HIGH passthrough=yes \
protocol=tcp
add action=mark-packet chain=forward comment=SUPER-HIGH-DOWNLOAD \
connection-mark=SUPER-HIGH dst-address-list=LAN new-packet-mark=\
SUPER-HIGH-DOWNLOAD passthrough=yes src-address-list=!LAN-EXCEPTION
add action=mark-packet chain=prerouting comment=SUPER-HIGH-UPLOAD \
connection-mark=SUPER-HIGH dst-address-list=!LAN-EXCEPTION \
new-packet-mark=SUPER-HIGH-UPLOAD passthrough=yes src-address-list=LAN
add action=accept chain=forward comment=\
"############## END SUPER-HIGH ##########" disabled=yes
-
- Сообщения: 69
- Зарегистрирован: 28 мар 2019, 08:40
Спасибо большое, парни! Признателен...